First Commit

2025-02-27 19:31:50 +01:00
parent bcbb6aff9a
commit e490df1715
2470 changed files with 1479965 additions and 0 deletions
--- a/libraries/NtpClientLib/examples/NTPClientESP8266/NTPClientESP8266.ino
+++ b/libraries/NtpClientLib/examples/NTPClientESP8266/NTPClientESP8266.ino
@@ -0,0 +1,156 @@
+/*
+Copyright 2016 German Martin (gmag11@gmail.com). All rights reserved.
+
+Redistribution and use in source and binary forms, with or without modification, are
+permitted provided that the following conditions are met :
+
+1. Redistributions of source code must retain the above copyright notice, this list of
+conditions and the following disclaimer.
+
+2. Redistributions in binary form must reproduce the above copyright notice, this list
+of conditions and the following disclaimer in the documentation and / or other materials
+provided with the distribution.
+
+THIS SOFTWARE IS PROVIDED BY <COPYRIGHT HOLDER> ''AS IS'' AND ANY EXPRESS OR IMPLIED
+WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND
+FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.IN NO EVENT SHALL <COPYRIGHT HOLDER> OR
+CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
+CONSEQUENTIAL DAMAGES(INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
+    SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON
+    ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT(INCLUDING
+        NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
+    ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+
+    The views and conclusions contained in the software and documentation are those of the
+    authors and should not be interpreted as representing official policies, either expressed
+    or implied, of German Martin
+*/
+
+/*
+ Name:		NtpClient.ino
+ Created:	20/08/2016
+ Author:	gmag11@gmail.com
+ Editor:	http://www.visualmicro.com
+*/
+
+#include <TimeLib.h>
+#include "WifiConfig.h"
+#include <NtpClientLib.h>
+#include <ESP8266WiFi.h>
+
+#ifndef WIFI_CONFIG_H
+#define YOUR_WIFI_SSID "YOUR_WIFI_SSID"
+#define YOUR_WIFI_PASSWD "YOUR_WIFI_PASSWD"
+#endif // !WIFI_CONFIG_H
+
+#define ONBOARDLED 2 // Built in LED on ESP-12/ESP-07
+#define SHOW_TIME_PERIOD 5000
+#define NTP_TIMEOUT 1500
+
+int8_t timeZone = 1;
+int8_t minutesTimeZone = 0;
+const PROGMEM char *ntpServer = "pool.ntp.org";
+bool wifiFirstConnected = false;
+
+void onSTAConnected (WiFiEventStationModeConnected ipInfo) {
+    Serial.printf ("Connected to %s\r\n", ipInfo.ssid.c_str ());
+}
+
+
+// Start NTP only after IP network is connected
+void onSTAGotIP (WiFiEventStationModeGotIP ipInfo) {
+    Serial.printf ("Got IP: %s\r\n", ipInfo.ip.toString ().c_str ());
+    Serial.printf ("Connected: %s\r\n", WiFi.status () == WL_CONNECTED ? "yes" : "no");
+    digitalWrite (ONBOARDLED, LOW); // Turn on LED
+    wifiFirstConnected = true;
+}
+
+// Manage network disconnection
+void onSTADisconnected (WiFiEventStationModeDisconnected event_info) {
+    Serial.printf ("Disconnected from SSID: %s\n", event_info.ssid.c_str ());
+    Serial.printf ("Reason: %d\n", event_info.reason);
+    digitalWrite (ONBOARDLED, HIGH); // Turn off LED
+    //NTP.stop(); // NTP sync can be disabled to avoid sync errors
+    WiFi.reconnect ();
+}
+
+void processSyncEvent (NTPSyncEvent_t ntpEvent) {
+    if (ntpEvent < 0) {
+        Serial.printf ("Time Sync error: %d\n", ntpEvent);
+        if (ntpEvent == noResponse)
+            Serial.println ("NTP server not reachable");
+        else if (ntpEvent == invalidAddress)
+            Serial.println ("Invalid NTP server address");
+        else if (ntpEvent == errorSending)
+            Serial.println ("Error sending request");
+        else if (ntpEvent == responseError)
+            Serial.println ("NTP response error");
+    } else {
+        if (ntpEvent == timeSyncd) {
+            Serial.print ("Got NTP time: ");
+            Serial.println (NTP.getTimeDateString (NTP.getLastNTPSync ()));
+        }
+    }
+}
+
+boolean syncEventTriggered = false; // True if a time even has been triggered
+NTPSyncEvent_t ntpEvent; // Last triggered event
+
+void setup () {
+    static WiFiEventHandler e1, e2, e3;
+
+    Serial.begin (115200);
+    Serial.println ();
+    WiFi.mode (WIFI_STA);
+    WiFi.begin (YOUR_WIFI_SSID, YOUR_WIFI_PASSWD);
+
+    pinMode (ONBOARDLED, OUTPUT); // Onboard LED
+    digitalWrite (ONBOARDLED, HIGH); // Switch off LED
+
+    NTP.onNTPSyncEvent ([](NTPSyncEvent_t event) {
+        ntpEvent = event;
+        syncEventTriggered = true;
+    });
+
+    // Deprecated
+    /*WiFi.onEvent([](WiFiEvent_t e) {
+        Serial.printf("Event wifi -----> %d\n", e);
+    });*/
+
+    e1 = WiFi.onStationModeGotIP (onSTAGotIP);// As soon WiFi is connected, start NTP Client
+    e2 = WiFi.onStationModeDisconnected (onSTADisconnected);
+    e3 = WiFi.onStationModeConnected (onSTAConnected);
+}
+
+void loop () {
+    static int i = 0;
+    static int last = 0;
+
+    if (wifiFirstConnected) {
+        wifiFirstConnected = false;
+        NTP.setInterval (63);
+        NTP.setNTPTimeout (NTP_TIMEOUT);
+        NTP.begin (ntpServer, timeZone, true, minutesTimeZone);
+    }
+
+    if (syncEventTriggered) {
+        processSyncEvent (ntpEvent);
+        syncEventTriggered = false;
+    }
+
+    if ((millis () - last) > SHOW_TIME_PERIOD) {
+        //Serial.println(millis() - last);
+        last = millis ();
+        Serial.print (i); Serial.print (" ");
+        Serial.print (NTP.getTimeDateString ()); Serial.print (" ");
+        Serial.print (NTP.isSummerTime () ? "Summer Time. " : "Winter Time. ");
+        Serial.print ("WiFi is ");
+        Serial.print (WiFi.isConnected () ? "connected" : "not connected"); Serial.print (". ");
+        Serial.print ("Uptime: ");
+        Serial.print (NTP.getUptimeString ()); Serial.print (" since ");
+        Serial.println (NTP.getTimeDateString (NTP.getFirstSync ()).c_str ());
+        Serial.printf ("Free heap: %u\n", ESP.getFreeHeap ());
+        i++;
+    }
+    delay (0);
+}